// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007
DEFINE OBJECTS 2
DEFINE OBJECT SANNY BUILDER 3.04      
DEFINE OBJECT WAREHOUSE_DOOR1          // Object number -1

DEFINE MISSIONS 1
DEFINE MISSION 0 AT @MISSN_10         

DEFINE EXTERNAL_SCRIPTS 0 // Use -1 in order not to compile AAA script

DEFINE UNKNOWN_EMPTY_SEGMENT 0

DEFINE UNKNOWN_THREADS_MEMORY 500

{$VERSION 3.1.0027}

//-------------MAIN---------------
thread 'MAIN' 
fade 0 0 
01F0: set_max_wanted_level_to 6 
set_wb_check_to 0 
00C0: set_current_time_hours_to 8 minutes_to 0 
023C: load_special_actor 'TENPEN' as 1 // models 290-299 
04E4: unknown_refresh_game_renderer_at 1541 -1675.4 
Camera.SetAtPos(1541.156, -1675.352, 13.55)
$PLAYER_CHAR = Player.Create(#NULL, 1550.68, -1675.49, 14.51)
Player.Build($PLAYER_CHAR)
09C7: change_player $PLAYER_CHAR model_to #SPECIAL01 
$PLAYER_ACTOR = Actor.EmulateFromPlayer($PLAYER_CHAR)
07AF: $PLAYER_GROUP = player $PLAYER_CHAR group 
set_weather 1 
wait 0 
Player.CanMove($PLAYER_CHAR) = False
select_interior 0 
0629: change_integer_stat 181 to 4 
062A: change_float_stat 165 to 800.0 
062A: change_float_stat 23 to 150.0 
062A: change_float_stat 21 to 200.0 
062A: change_float_stat 160 to 150.0 
0629: change_integer_stat 68 to 10 
016C: restart_if_wasted_at 2027.77 -1420.52 15.99 angle 137.0 town_number 0 
016D: restart_if_busted_at 1550.68 -1675.49 14.51 angle 90.0 town_number 0 
0180: set_on_mission_flag_to $ONMISSION // Note: your missions have to use the variable defined here 
$DEFAULT_WAIT_TIME = 250 
03E6: remove_text_box 
$ONMISSION = 0 
$CRASH_MARKER = Marker.CreateIconAndSphere(16, 1541.156, -1675.352, 13.552)
Player.CanMove($PLAYER_CHAR) = True
fade 1 500 
wait 1000 
Player.CanMove($PLAYER_CHAR) = True
Camera.Restore_WithJumpCut
Camera.SetBehindPlayer
$test = 1 

:MAIN_321
wait $DEFAULT_WAIT_TIME 
00BF: $Time_Hours = current_time_hours, $Time_Mins = current_time_minutes 
if and
  $ONMISSION == 0 
00ED:   actor $PLAYER_ACTOR 0 near_point 1541.156 -1675.352 radius 1.0 1.0 on_foot 
jf @MAIN_388 
Marker.Disable($CRASH_MARKER)
start_mission 0 

:MAIN_388
jump @MAIN_321 

//-------------Mission 0---------------

:MISSN_10
thread 'MISSN_10' 
gosub @MISSN_10_70 
if 
wasted_or_busted 
jf @MISSN_10_61 
$CRASH_MARKER = Marker.CreateIconAndSphere(16, 1541.156, -1675.352, 13.552)

:MISSN_10_61
gosub @MISSN_10_6494 
end_thread 

:MISSN_10_70
fade 0 0 

:MISSN_10_76
wait 0 
if 
   not fading 
jf @MISSN_10_76 
00C0: set_current_time_hours_to 6 minutes_to 15 
set_weather 9 
0395: clear_area 1 at -939.0071 -2442.519 88.9969 radius 50.0 
Camera.SetAtPos(-939.5, -2442.0, 88.9969)
Actor.PutAt($PLAYER_ACTOR, -934.5698, -2431.392, 82.9687)
Actor.Angle($PLAYER_ACTOR) = 323.0
067C: put_camera_on_actor $PLAYER_ACTOR with_offset 2.5 7.0 1.0 rotation 0.0 0.0 0.0 0.0 2 
023C: load_special_actor 'TRUTH' as 2 // models 290-299 
Model.Load(#SADLSHIT)
Model.Load(#BAGBOXA)
Model.Load(#BAGGAGE)
Model.Load(#DWMOLC2)
Model.Load(#CWFYHB)
Model.Load(#CWMOFR)
Model.Load(#CWMOHB1)
Model.Load(#WMOMIB)
Model.Load(#CUNTGUN)
Model.Load(#WALTON)
Model.Load(#WMYBP)
038B: load_requested_models 

:MISSN_10_284
wait 0 
if and
   Model.Available(#SADLSHIT)
   Model.Available(#BAGBOXA)
   Model.Available(#BAGGAGE)
   Model.Available(#DWMOLC2)
   Model.Available(#WALTON)
   Model.Available(#WMYBP)
jf @MISSN_10_284 
if and
   Model.Available(#CWFYHB)
   Model.Available(#CWMOFR)
   Model.Available(#CWMOHB1)
   Model.Available(#WMOMIB)
   Model.Available(#CUNTGUN)
023D:   special_actor 2 loaded 
jf @MISSN_10_284 
17@ = Actor.Create(Mission1, #WMOMIB, -932.0044, -2432.423, 82.6937)
Actor.Health(17@) = 200
Actor.Angle(17@) = 323.0
15@ = Actor.Create(Mission1, #SPECIAL02, -935.3608, -2429.718, 82.3529)
Actor.Health(15@) = 200
Actor.Angle(15@) = 323.0
0631: put_actor 15@ in_group $PLAYER_GROUP 
054C: use_GXT_table 'JABM10' 
12@ = Car.Create(#SADLSHIT, -894.1255, -2375.919, 52.9778)
13@ = Car.Create(#BAGGAGE, -821.3815, -2442.865, 68.9761)
14@ = Car.Create(#BAGBOXA, -817.3062, -2452.05, 72.3128)
Car.Angle(12@) = 225.0
Car.Angle(13@) = 53.68
Car.Angle(14@) = 53.68
0229: set_car 12@ primary_color_to 3 secondary_color_to 0 //Red Truck - mythology
0893: put_trailer 14@ on_cab 13@ 
0129: 16@ = create_actor_pedtype 5 model #DWMOLC2 in_car 13@ driverseat 
Actor.Health(16@) = 200
0615: define_AS_pack_begin 2@ 
05D1: AS_actor -1 drive_car -1 to -898.6368 -2382.527 52.8651 speed 10.0 2 model #BAGGAGE 5 
05D1: AS_actor -1 drive_car -1 to -1015.295 -2611.826 83.1478 speed 15.0 0 model #BAGGAGE 5 
05D1: AS_actor -1 drive_car -1 to -1142.317 -2283.812 36.0892 speed 20.0 0 model #BAGGAGE 5 
05D1: AS_actor -1 drive_car -1 to -855.9761 -1866.536 88.9344 speed 20.0 0 model #BAGGAGE 5 
05D1: AS_actor -1 drive_car -1 to -827.9308 -1813.534 91.5895 speed 20.0 2 model #BAGGAGE 5 
05D1: AS_actor -1 drive_car -1 to -1037.289 -1148.345 128.9824 speed 15.0 0 model #BAGGAGE 5 
0616: define_AS_pack_end 2@ 
0618: assign_actor 16@ to_AS_pack 2@ 
061B: remove_references_to_AS_pack 2@ 
wait 1000 
02A3: enable_widescreen 1 
fade 1 500 
//Spooky's dialog
:MISSN_10_845
wait 0 
if 
   not fading 
jf @MISSN_10_845 
100@ = 0 
05BF: AS_actor 17@ look_at_actor 15@ 5000 ms 
00BC: show_text_highpriority GXT 'EC01' time 5000 flag 1  // Hey there Truth, is this the cop you were telling me about?
03CF: load_wav 44400 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_1268 
00BC: show_text_highpriority GXT 'EC02' time 5000 flag 1  // Apparently.
03CF: load_wav 41411 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_1268 
05BF: AS_actor 17@ look_at_actor $PLAYER_ACTOR 5000 ms 
00BC: show_text_highpriority GXT 'EC03' time 5000 flag 1  // Ok here's the deal, you see this guy down in the pass?
03CF: load_wav 44401 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_1268 
067C: put_camera_on_actor 16@ with_offset 1.5 3.0 1.0 rotation 0.0 0.0 0.0 0.0 2 
00BC: show_text_highpriority GXT 'EC04' time 5000 flag 1  // He picks up new people for this cult farm.
03CF: load_wav 44402 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_1268 
067C: put_camera_on_actor 15@ with_offset -5.5 5.0 1.0 rotation 0.0 0.0 0.0 0.0 2 
00BC: show_text_highpriority GXT 'EC05' time 5000 flag 1  // I want the both of you to get me the evidence about the inner workings.
03CF: load_wav 44403 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_1268 
05BF: AS_actor 17@ look_at_actor 15@ 5000 ms 
00BC: show_text_highpriority GXT 'EC06' time 5000 flag 1  // I will pay you ten large for the Epsilon Tract.
03CF: load_wav 44404 as 1 
gosub @MISSN_10_6321 

:MISSN_10_1268
90@ = Marker.CreateAboveCar(13@)
07E0: set_marker 90@ type_to 2 
Marker.SetColor(90@, 0)
100@ = 99 
02A3: enable_widescreen 0 
Player.CanMove($PLAYER_CHAR) = True
Camera.Restore_WithJumpCut
Camera.SetBehindPlayer
03E5: show_text_box 'EC07'  // You and Truth need to follow this guy and find a way inside the cult farm.  Don't allow the Truth to be killed.
060A: create_decision_maker_type 2 store_to 98@ // decision\allowed\m_.ped files 
01EB: set_traffic_density_multiplier_to 0.3 
41@ = Actor.Create(Gang10, #CWFYHB, -1016.771, -2626.34, 96.769)
42@ = Actor.Create(Gang10, #CWMOFR, -960.157, -2615.855, 102.6525)
43@ = Actor.Create(Gang10, #CWMOHB1, -910.7773, -2591.279, 103.3707)
44@ = 0 
01B2: give_actor 41@ weapon 33 ammo 999 // Load the weapon model before using this 
060B: set_actor 41@ decision_maker_to 98@ 
Actor.WeaponAccuracy(41@) = 50
01B2: give_actor 42@ weapon 33 ammo 999 // Load the weapon model before using this 
060B: set_actor 42@ decision_maker_to 98@ 
Actor.WeaponAccuracy(42@) = 75
01B2: give_actor 43@ weapon 33 ammo 999 // Load the weapon model before using this 
060B: set_actor 43@ decision_maker_to 98@ 
Actor.WeaponAccuracy(43@) = 25
//This section defines the sniper's actions
0615: define_AS_pack_begin 1@ 
0605: actor -1 perform_animation_sequence "SWT_WLLPK_L" IFP_file "SWAT" 8.0 loop 0 0 0 0 time -1 // versionA 
0605: actor -1 perform_animation_sequence "SWT_WLLSHOOT_IN_L" IFP_file "SWAT" 8.0 loop 0 1 1 0 time -1 // versionA 
0638: AS_actor -1 stay_put 1 
07A5: AS_actor -1 attack_actor $PLAYER_ACTOR 1500 ms 
0638: AS_actor -1 stay_put 0 
0605: actor -1 perform_animation_sequence "SWT_WLLSHOOT_OUT_L" IFP_file "SWAT" 8.0 loop 0 1 1 0 time -1 // versionA 
0605: actor -1 perform_animation_sequence "SWT_WLLPK_L_BACK" IFP_file "SWAT" 8.0 loop 0 0 0 0 time -1 // versionA 
0643: set_AS_pack 1@ loop 1 
0616: define_AS_pack_end 1@ 
0618: assign_actor 41@ to_AS_pack 1@ 
0618: assign_actor 42@ to_AS_pack 1@ 
0618: assign_actor 43@ to_AS_pack 1@ 
061B: remove_references_to_AS_pack 1@ 
//Dialog Flags 
48@ = 0  //Sniper warning                    
49@ = 0  //In car = 1 Outside car = 0        
51@ = 0  //Car shot by sniper                
52@ = 0  //Car damaged by collision          
53@ = 0  //Truth falling behind              
54@ = 0  //Lost Trenchcoat                   
55@ = 0  //Ditched the Truth                 
Actor.DestroyWithFade(17@)
//Main Loop driving to the farm  
:MISSN_10_1786
wait 0 
//More Tuskin Raiders... LOL this part moves the same 3 snipers to the next location.
//If you read this code correctly there is a few simple ways to beat the snipers. You can simply avoid
//their locations by taking an altenate route or kill the 3 snipers.  The code is written in such a way 
//that it just seems there are 12 along your route. This is a "free thinking" mission.
if and
  44@ == 0 
00EE:   actor $PLAYER_ACTOR 0 near_point -1010.11 -2034.8 radius 250.0 250.0 in_car 
jf @MISSN_10_1909 
Actor.PutAt(41@, -983.9795, -1983.063, 83.0908)
Actor.PutAt(42@, -1011.406, -2038.512, 73.9969)
Actor.PutAt(43@, -1034.954, -2082.835, 67.6768)
44@ = 1 
51@ = 0 

:MISSN_10_1909
if and
  44@ == 1 
00EE:   actor $PLAYER_ACTOR 0 near_point -727.18 -1590.93 radius 250.0 250.0 in_car 
jf @MISSN_10_2028 
Actor.PutAt(41@, -780.774, -1644.634, 111.3823)
Actor.PutAt(42@, -704.2275, -1530.029, 56.7948)
Actor.PutAt(43@, -675.0509, -1574.371, 28.9919)
44@ = 2 
51@ = 0 

:MISSN_10_2028
if and
  44@ == 2 
00EE:   actor $PLAYER_ACTOR 0 near_point -879.22 -1145.97 radius 250.0 250.0 in_car 
jf @MISSN_10_2147 
Actor.PutAt(41@, -880.0371, -1334.419, 123.8063)
Actor.PutAt(42@, -860.2943, -1027.02, 90.9599)
Actor.PutAt(43@, -889.9305, -1068.75, 100.8111)
44@ = 3 
51@ = 0 
//sniper warning
:MISSN_10_2147
if and
  48@ == 0 
00EE:   actor $PLAYER_ACTOR 0 near_point -915.576 -2579.699 radius 40.0 40.0 in_car 
jf @MISSN_10_2210 
48@ = 1 
03E5: show_text_box 'EC08'  // There are cultist snipers on the ridge!

//This section is just the Truth's random dialog.
:MISSN_10_2210
if 
   not Actor.Driving($PLAYER_ACTOR)
jf @MISSN_10_2368 
if 
  49@ == 0 
jf @MISSN_10_2294 
49@ = 1 
51@ = 0 
52@ = 0 
0209: 50@ = random_int_in_ranges 41415 41418 //Truth tells you to get another car.
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 

:MISSN_10_2294
if and
  53@ == 0 
80F2:   not actor $PLAYER_ACTOR near_actor 15@ radius 10.0 10.0 0 
jf @MISSN_10_2368 
53@ = 1 
0209: 50@ = random_int_in_ranges 41407 41411 //Truth tells you to slow up.
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 

:MISSN_10_2368
if 
   Actor.Driving($PLAYER_ACTOR)
jf @MISSN_10_2544 
if 
  49@ == 1 
jf @MISSN_10_2424 
12@ = Actor.Car($PLAYER_ACTOR)
49@ = 0 
53@ = 0 

:MISSN_10_2424
if and
  51@ == 0 
031E:   car 12@ hit_by_weapon 33 
jf @MISSN_10_2485 
51@ = 1 
0209: 50@ = random_int_in_ranges 41418 41422 //Truth tell you to drive faster! You are being shot at.
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 

:MISSN_10_2485
if and
  52@ == 0 
03C9:   car 12@ damaged 
jf @MISSN_10_2544 
52@ = 1 
0209: 50@ = random_int_in_ranges 41422 41424 //Truth comments on your wreckless driving.
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 
//Make sure the Truth is alive.
:MISSN_10_2544
if 
   not Actor.Dead(15@)
jf @MISSN_10_6454 
//Lost Trenchcoat Man
if and
  54@ == 0 
80F2:   not actor $PLAYER_ACTOR near_actor 16@ radius 400.0 400.0 0 
jf @MISSN_10_2621 
54@ = 1 
03E5: show_text_box 'EC17'  // You lost the Trenchcoat Man. Can you find the cult farm on your own?
Marker.Disable(90@)

:MISSN_10_2621
if and
  55@ == 0 
80F2:   not actor $PLAYER_ACTOR near_actor 15@ radius 200.0 200.0 0 
jf @MISSN_10_2677 
55@ = 1 
03E5: show_text_box 'EC19'  // You ditched the Truth. You should go back for him.
//Found the Farm
:MISSN_10_2677
if 
00EE:   actor $PLAYER_ACTOR 1 near_point -1065.514 -1361.391 radius 10.0 10.0 in_car 
jf @MISSN_10_1786 
03E5: show_text_box 'EC18'  // You found the farm, now find your way inside.
wait 1000 
fade 0 500 

:MISSN_10_2738
wait 0 
if 
   not fading 
jf @MISSN_10_2738 
068B: set_car 12@ all_disembark 
if 
  54@ == 0 
jf @MISSN_10_2783 
Marker.Disable(90@)

:MISSN_10_2783
Actor.DestroyWithFade(16@)
Car.Destroy(13@)
Car.Destroy(14@)
wait 1000 
00C0: set_current_time_hours_to 23 minutes_to 50 
fade 1 500 

:MISSN_10_2816
wait 0 
if 
   not fading 
jf @MISSN_10_2816 

:MISSN_10_2833
wait 0 
if 
00ED:   actor $PLAYER_ACTOR 1 near_point -1060.784 -1205.421 radius 1.0 1.0 on_foot 
jf @MISSN_10_2833 
fade 0 1500 

:MISSN_10_2882
wait 0 
if 
   not fading 
jf @MISSN_10_2882 
02A3: enable_widescreen 1 
Actor.PutAt($PLAYER_ACTOR, -79.5743, -103.2505, 6.4844)
Actor.Angle($PLAYER_ACTOR) = 260.0
Actor.PutAt(15@, -85.7385, -102.4936, 3.4844)
111@ = Object.Create(#WAREHOUSE_DOOR1, -70.99, -103.2, 6.8)
112@ = Object.Create(#WAREHOUSE_DOOR1, -71.38, -105.79, 6.8)
113@ = Object.Create(#WAREHOUSE_DOOR1, -70.99, -103.2, 9.6)
114@ = Object.Create(#WAREHOUSE_DOOR1, -71.38, -105.79, 9.6)
//Home made cross door in Blueberry barn loft.
:MISSN_10_3041
wait 0 
if and
03CA:   object 111@ exists 
03CA:   object 112@ exists 
03CA:   object 113@ exists 
03CA:   object 114@ exists 
jf @MISSN_10_3041 
Object.PutAt(111@, -70.99, -103.2, 6.8)
Object.PutAt(112@, -71.38, -105.79, 6.8)
Object.PutAt(113@, -70.99, -103.2, 9.6)
Object.PutAt(114@, -71.38, -105.79, 9.6)
0453: set_object 111@ XY_rotation 0.0 0.0 angle 260.0 
0453: set_object 112@ XY_rotation 0.0 0.0 angle 260.0 
0453: set_object 113@ XY_rotation 0.0 0.0 angle 260.0 
0453: set_object 114@ XY_rotation 0.0 0.0 angle 260.0 
21@ = Actor.Create(Mission1, #CWFYHB, -74.16, -103.0, 6.55)
Actor.Angle(21@) = 80.0
22@ = Actor.Create(Mission1, #DWMOLC2, -74.16, -104.0, 6.55)
Actor.Angle(22@) = 80.0
23@ = Actor.Create(Mission1, #WMYBP, -74.16, -105.0, 6.55)
Actor.Angle(23@) = 80.0
0605: actor 21@ perform_animation_sequence "IDLE_STANCE" IFP_file "PED" 4.0 loop 1 0 0 0 time -1 // versionA 
0605: actor 22@ perform_animation_sequence "IDLE_STANCE" IFP_file "PED" 4.0 loop 1 0 0 0 time -1 // versionA 
0605: actor 23@ perform_animation_sequence "IDLE_STANCE" IFP_file "PED" 4.0 loop 1 0 0 0 time -1 // versionA 
05BA: AS_actor 21@ move_mouth -1 ms 
05BA: AS_actor 22@ move_mouth -1 ms 
05BA: AS_actor 23@ move_mouth -1 ms 
067C: put_camera_on_actor 22@ with_offset 0.5 8.0 1.0 rotation 0.0 0.0 0.0 0.0 2 
wait 2000 
fade 1 1500 
//Dialog for the cultists
:MISSN_10_3528
wait 0 
if 
   not fading 
jf @MISSN_10_3528 
100@ = 0 
00BC: show_text_highpriority GXT 'EC10' time 10000 flag 1  // Kifflom! I know you have come for the tract. If you are meant to have it,
03CF: load_wav 44405 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_3841 
00BC: show_text_highpriority GXT 'EC11' time 10000 flag 1  // there is nothing I can do to stop you. You see this world is not real.
03CF: load_wav 44406 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_3841 
00BC: show_text_highpriority GXT 'EC12' time 10000 flag 1  // I and many others are just puppets inside a virtual holographic reality.
03CF: load_wav 44407 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_3841 
00BC: show_text_highpriority GXT 'EC13' time 10000 flag 1  // At all times, there is one of us who is the desendant of Kraff,
03CF: load_wav 44408 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_3841 
00BC: show_text_highpriority GXT 'EC14' time 10000 flag 1  // Emperor of the 4th Paradigm. Are you the player this time?
03CF: load_wav 44409 as 1 
gosub @MISSN_10_6321 
if 
  100@ == 0 
jf @MISSN_10_3841 
00BC: show_text_highpriority GXT 'EC15' time 10000 flag 1  // I cannot stop you but the ones outside will try.
03CF: load_wav 44410 as 1 
gosub @MISSN_10_6321 
100@ = 99 

:MISSN_10_3841
fade 0 1500 

:MISSN_10_3848
wait 0 
if 
   not fading 
jf @MISSN_10_3848 
if 
   Car.Wrecked(12@)
jf @MISSN_10_3921 
12@ = Car.Create(#WALTON, -1045.496, -1215.99, 128.4884)
Car.Angle(12@) = 174.0
jump @MISSN_10_3973 

:MISSN_10_3921
Car.StorePos(12@, 3@, 4@, 5@)
6@ = Car.Angle(12@)
Car.Destroy(12@)
12@ = Car.Create(#WALTON, 3@, 4@, 5@)
Car.Angle(12@) = 6@

:MISSN_10_3973
Actor.PutAt($PLAYER_ACTOR, -1058.229, -1206.415, 129.2007)
072A: put_actor 15@ into_car 12@ driverseat 
13@ = Car.Create(#WALTON, -1055.496, -1145.99, 128.4884)
Car.Angle(13@) = 174.0
0129: 16@ = create_actor_pedtype 5 model #DWMOLC2 in_car 13@ driverseat 
0464: put_actor 42@ into_turret_on_car 13@ at_car_offset 0.0 -0.7 0.5 position 2 shooting_angle_limit 360.0 with_weapon 33 
14@ = Car.Create(#WALTON, -1050.496, -1145.99, 128.4884)
Car.Angle(14@) = 174.0
0129: 17@ = create_actor_pedtype 5 model #WMYBP in_car 14@ driverseat 
0464: put_actor 41@ into_turret_on_car 14@ at_car_offset 0.0 -0.7 0.5 position 2 shooting_angle_limit 360.0 with_weapon 33 
18@ = Car.Create(#WALTON, -1045.496, -1145.99, 128.4884)
Car.Angle(18@) = 174.0
0129: 19@ = create_actor_pedtype 5 model #CWMOFR in_car 18@ driverseat 
0464: put_actor 43@ into_turret_on_car 18@ at_car_offset 0.0 -0.7 0.5 position 2 shooting_angle_limit 360.0 with_weapon 33 
Camera.SetBehindPlayer
Camera.Restore
wait 1000 
fade 1 1500 

:MISSN_10_4249
wait 0 
if 
   not fading 
jf @MISSN_10_4249 
03E5: show_text_box 'EC16'  // Get back to the car and get the book to the drop.
49@ = 0 
02A3: enable_widescreen 0 

:MISSN_10_4288
wait 0 
if and
  49@ == 0 
00F2:   actor 15@ near_actor $PLAYER_ACTOR radius 30.0 30.0 0 
jf @MISSN_10_4385 
Player.CanMove($PLAYER_CHAR) = False
0209: 50@ = random_int_in_ranges 41400 41404 
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 
05CA: AS_actor $PLAYER_ACTOR enter_car 12@ passenger_seat 0 -1 ms 
49@ = 1 
//Put Player in the flatbed with an AK47
:MISSN_10_4385
if 
   Actor.InCar($PLAYER_ACTOR, 12@)
jf @MISSN_10_4288 
Player.CanMove($PLAYER_CHAR) = True
0792: disembark_instantly_actor $PLAYER_ACTOR 
0464: put_actor $PLAYER_ACTOR into_turret_on_car 12@ at_car_offset 0.0 -0.7 0.6 position 2 shooting_angle_limit 360.0 with_weapon 30 
0858: set_player $PLAYER_CHAR scan_horizon_to_angle 90.0 rotation_speed 180.0 
Camera.Restore
//Paths for the Truth and the other trucks to follow.
0615: define_AS_pack_begin 8@ 
05D1: AS_actor -1 drive_car -1 to -1050.471 -1357.004 129.6888 speed 20.0 2 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -931.5592 -1427.13 126.8859 speed 20.0 2 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -867.1517 -1554.513 126.5726 speed 20.0 2 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -957.2097 -1636.811 75.6743 speed 20.0 2 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -977.7735 -1719.473 77.5703 speed 20.0 2 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -894.7231 -1722.691 76.809 speed 20.0 2 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -884.4046 -1861.301 87.6698 speed 20.0 2 model #NULL 5 
0616: define_AS_pack_end 8@ 
0615: define_AS_pack_begin 9@ 
05D1: AS_actor -1 drive_car -1 to -1014.678 -1906.086 78.3388 speed 35.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -1157.828 -1895.382 77.8521 speed 35.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -1208.729 -1784.658 48.5271 speed 35.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -1312.426 -1689.136 45.2692 speed 35.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -1494.074 -1607.809 40.4293 speed 35.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -1607.76 -1609.948 35.9059 speed 35.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -1884.414 -1757.79 28.8901 speed 35.0 3 model #NULL 5 
0616: define_AS_pack_end 9@ 
0615: define_AS_pack_begin 10@ 
05D1: AS_actor -1 drive_car -1 to -2059.589 -1951.438 54.7287 speed 30.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -2107.416 -2076.61 62.7122 speed 30.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -2244.252 -2197.325 35.3106 speed 30.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -2259.446 -2229.482 29.6217 speed 20.0 3 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -2157.723 -2317.613 30.1259 speed 10.0 0 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -2212.886 -2426.209 30.126 speed 10.0 0 model #NULL 5 
05D1: AS_actor -1 drive_car -1 to -2164.772 -2458.857 30.2715 speed 10.0 0 model #NULL 5 
0616: define_AS_pack_end 10@ 
0618: assign_actor 15@ to_AS_pack 8@ 
0618: assign_actor 16@ to_AS_pack 8@ 
0618: assign_actor 17@ to_AS_pack 8@ 
0618: assign_actor 19@ to_AS_pack 8@ 
061B: remove_references_to_AS_pack 8@ 
0209: 50@ = random_int_in_ranges 41404 41407 
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 

:MISSN_10_5233
wait 0 
if and
   not Car.Wrecked(12@)
   not Actor.Dead(15@)
jf @MISSN_10_6454 
if 
00EE:   actor 15@ 0 near_point -884.4046 -1861.301 radius 25.0 25.0 in_car 
jf @MISSN_10_5233 
13@ = Car.Create(#WALTON, -830.37, -1841.39, 91.2085)
Car.Angle(13@) = 156.0
0129: 16@ = create_actor_pedtype 5 model #DWMOLC2 in_car 13@ driverseat 
0464: put_actor 42@ into_turret_on_car 13@ at_car_offset 0.0 -0.7 0.5 position 2 shooting_angle_limit 360.0 with_weapon 33 
14@ = Car.Create(#WALTON, -989.9664, -1825.613, 93.4106)
Car.Angle(14@) = 174.0
0129: 17@ = create_actor_pedtype 5 model #WMYBP in_car 14@ driverseat 
0464: put_actor 41@ into_turret_on_car 14@ at_car_offset 0.0 -0.7 0.5 position 2 shooting_angle_limit 360.0 with_weapon 33 
18@ = Car.Create(#WALTON, -994.0031, -1920.762, 79.9116)
Car.Angle(18@) = 174.0
0129: 19@ = create_actor_pedtype 5 model #CWMOFR in_car 18@ driverseat 
0464: put_actor 43@ into_turret_on_car 18@ at_car_offset 0.0 -0.7 0.5 position 2 shooting_angle_limit 360.0 with_weapon 33 
0618: assign_actor 15@ to_AS_pack 9@ 
0618: assign_actor 16@ to_AS_pack 9@ 
0618: assign_actor 17@ to_AS_pack 9@ 
0618: assign_actor 19@ to_AS_pack 9@ 
061B: remove_references_to_AS_pack 9@ 
0209: 50@ = random_int_in_ranges 41404 41407 
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 

:MISSN_10_5594
wait 0 
if and
   not Car.Wrecked(12@)
   not Actor.Dead(15@)
jf @MISSN_10_6454 
if 
00EE:   actor 15@ 0 near_point -1884.414 -1757.79 radius 25.0 25.0 in_car 
jf @MISSN_10_5594 
0618: assign_actor 15@ to_AS_pack 10@ 
061B: remove_references_to_AS_pack 10@ 
//Revive the 3 snipers
41@ = Actor.Create(Gang10, #CWFYHB, -2059.201, -1981.75, 71.4711)
42@ = Actor.Create(Gang10, #CWMOFR, -2086.329, -1942.7, 77.9656)
43@ = Actor.Create(Gang10, #CWMOHB1, -2116.111, -2003.686, 79.9164)
01B2: give_actor 41@ weapon 33 ammo 999 // Load the weapon model before using this 
060B: set_actor 41@ decision_maker_to 98@ 
Actor.WeaponAccuracy(41@) = 50
01B2: give_actor 42@ weapon 33 ammo 999 // Load the weapon model before using this 
060B: set_actor 42@ decision_maker_to 98@ 
Actor.WeaponAccuracy(42@) = 50
01B2: give_actor 43@ weapon 33 ammo 999 // Load the weapon model before using this 
060B: set_actor 43@ decision_maker_to 98@ 
Actor.WeaponAccuracy(43@) = 50
0615: define_AS_pack_begin 1@ 
0605: actor -1 perform_animation_sequence "SWT_WLLPK_L" IFP_file "SWAT" 8.0 loop 0 0 0 0 time -1 // versionA 
0605: actor -1 perform_animation_sequence "SWT_WLLSHOOT_IN_L" IFP_file "SWAT" 8.0 loop 0 1 1 0 time -1 // versionA 
0638: AS_actor -1 stay_put 1 
07A5: AS_actor -1 attack_actor $PLAYER_ACTOR 1500 ms 
0638: AS_actor -1 stay_put 0 
0605: actor -1 perform_animation_sequence "SWT_WLLSHOOT_OUT_L" IFP_file "SWAT" 8.0 loop 0 1 1 0 time -1 // versionA 
0605: actor -1 perform_animation_sequence "SWT_WLLPK_L_BACK" IFP_file "SWAT" 8.0 loop 0 0 0 0 time -1 // versionA 
0643: set_AS_pack 1@ loop 1 
0616: define_AS_pack_end 1@ 
0618: assign_actor 41@ to_AS_pack 1@ 
0618: assign_actor 42@ to_AS_pack 1@ 
0618: assign_actor 43@ to_AS_pack 1@ 
061B: remove_references_to_AS_pack 1@ 
0209: 50@ = random_int_in_ranges 41404 41407 
03CF: load_wav 50@ as 1 
gosub @MISSN_10_6321 

:MISSN_10_6087
wait 0 
if and
   not Car.Wrecked(12@)
   not Actor.Dead(15@)
jf @MISSN_10_6454 
if 
00EE:   actor 15@ 0 near_point -2259.44 -2229.48 radius 25.0 25.0 in_car 
jf @MISSN_10_6165 

0465: remove_actor $PLAYER_ACTOR from_turret_mode 
0430: put_actor $PLAYER_ACTOR into_car 12@ passenger_seat 0 

:MISSN_10_6165
if and
   not Car.Wrecked(12@)
   not Actor.Dead(15@)
jf @MISSN_10_6454 
if or
00ED:   actor $PLAYER_ACTOR 0 near_point -2162.706 -2462.167 radius 10.0 10.0 on_foot 
00EE:   actor $PLAYER_ACTOR 1 near_point -2162.706 -2462.167 radius 10.0 10.0 in_car 
jf @MISSN_10_6087 
03CF: load_wav 41432 as 1 
gosub @MISSN_10_6321 
$CRASH_TOTAL_PASSED_MISSIONS += 1 
030C: progress_made += 1 
0394: play_music 1 
Player.ClearWantedLevel($PLAYER_CHAR)
01E3: show_text_1number_styled GXT 'M_PASS' number 10000 time 5000 style 1  // MISSION PASSED!~n~~w~$~1~
Player.Money($PLAYER_CHAR) += 10000
wait 5000 
return 
//Audio Subroutine
:MISSN_10_6321
if 
  100@ == 99 
jf @MISSN_10_6346 
0949: link_wav 1 to_actor 15@ 

:MISSN_10_6346
wait 0 
if 
03D0:   wav 1 loaded 
jf @MISSN_10_6346 
03D1: play_wav 1 
//Skip Cut
:MISSN_10_6369
wait 0 
if 
  100@ == 0 
jf @MISSN_10_6433 
if or
00E1:   player 0 pressed_key 15 
00E1:   player 0 pressed_key 16 
00E1:   player 0 pressed_key 17 
jf @MISSN_10_6433 
100@ = 1 
040D: unload_wav 1 
return 

:MISSN_10_6433
if 
03D2:   wav 1 ended 
jf @MISSN_10_6369 
040D: unload_wav 1 
return 

:MISSN_10_6454
$CRASH_MARKER = Marker.CreateIconAndSphere(16, 1597.343, -1515.328, 13.5899)
00BA: show_text_styled GXT 'M_FAIL' time 5000 style 1  // ~r~MISSION FAILED!
return 

:MISSN_10_6494
$ONMISSION = 0 
Marker.Disable(90@)
Model.Destroy(#SADLSHIT)
Model.Destroy(#BAGBOXA)
Model.Destroy(#BAGGAGE)
Model.Destroy(#DWMOLC2)
Model.Destroy(#CWFYHB)
Model.Destroy(#CWMOFR)
Model.Destroy(#CWMOHB1)
Model.Destroy(#WMOMIB)
Model.Destroy(#CUNTGUN)
Model.Destroy(#WALTON)
Model.Destroy(#WMYBP)
mission_cleanup 
return 
{Audio for The Truth edited by Vincent "ToonSkull"
41400 - Get in the car quick!
41401 - Get in the car it's a faraday cage man.
41402 - Come on, get the fuck in!
41403 - Come on, get in dude.
41404 - You know I hate driving.
41405 - I forgot which pedels steer.
41406 - Think about a yellow rubber duck.
41407 - Dude, wait up man!
41408 - Yo! Wait up duded.
41409 - Slow down man I can't keep up!
41410 - Don't desert me friend!
41411 - Apparently.
41415 - Oh, we're gonna need some more wheeels!
41416 - We need to get some new wheels.
41417 - Oh man we need a polluter.
41418 - Go go go!
41419 - Now punch it man!
41420 - Get us the fuck out of here now!
41421 - We need the next dimension dude!
41422 - Whoa man this is an interesting way to travel!
41423 - Are you controling this thing or what?
41432 - Farout have a nice trip dude!}